# file      : tests/function/install/testscript
# license   : MIT; see accompanying LICENSE file

.include ../../common.testscript

+cat <<EOI >+build/bootstrap.build
using config
using install
EOI

root = ($cxx.target.class != 'windows' ? '/usr/' : 'C:\')

+cat <<"EOI" >=build/config.build
config.version = 1
config.install.root = $root
EOI

: realize
:
{{
  : existing
  :
  a = ($cxx.target.class != 'windows' ? '/usr/lib/a/' : 'C:\lib\a\');
  $* <'print $install.resolve([dir_path] lib/a)' >$a

  : non-existing
  :
  $* <'print $install.resolve([dir_path] foo/a)' 2>>EOE != 0
  error: unknown installation directory name 'foo'
    info: did you forget to specify config.install.foo?
    info: specify !config.install.foo=... if installing from multiple projects
    <stdin>:1:8: info: while calling install.resolve(dir_path)
  EOE
}}
