# file      : bbot/bootstrap-manifest.test.testscript
# license   : MIT; see accompanying LICENSE file

: bootstrap-manifest
:
{{
  : valid
  :
  $* <<EOF >>EOF
  : 1
  bbot-version: 1.1.2
  libbbot-version: 1.1.1
  EOF

  : dup
  :
  $* <<EOI 2>'stdin:3:1: error: bbot-version redefinition' == 1
  : 1
  bbot-version: 1.1.2
  bbot-version: 1.1.3
  EOI

  : invalid-version
  :
  $* <<EOI 2>'stdin:2:15: error: invalid package version: invalid major version' == 1
  : 1
  bbot-version: abc
  EOI

  : no-versions
  :
  $* <<EOI 2>'stdin:2:1: error: no package versions specified' == 1
  : 1
  EOI

  : unknown
  :
  $* <<EOI 2>"stdin:2:1: error: unknown name 'x' in bootstrap manifest" == 1
  : 1
  x: y
  EOI
}}
